BCD - для Windows 7

Обсуждение статьи "Установка Windows Vista и Windows 7 по сети"

Модераторы: editor, Devils

BCD - для Windows 7

Сообщение The_Futurist » 26 июл 2009, 18:38

Вопрос собсна, скрипт который сдесь приведен не подходит не обычная версия не исправленная, пишется 0xc000001 ошибка во время чтения BCD...
The_Futurist
 
Сообщения: 1
Зарегистрирован: 26 июл 2009, 18:34

Re: BCD - для Windows 7

Сообщение BoRoDa » 09 дек 2009, 16:15

Вот мой пример createbcd.cmd, чудесно работающий одновременно для семёрки и для висты.
Нужно только поменять пути.


Код: Выделить всё
set BCD-File=D:\Netboot\Seven\boot\BCD
del %BCD-File%
Bcdedit /createstore %BCD-File%
Bcdedit /store %BCD-File% /create {ramdiskoptions} /d "Ramdisk Option"
Bcdedit /store %BCD-File% /set {ramdiskoptions} ramdisksdidevice  boot
Bcdedit /store %BCD-File% /set {ramdiskoptions} ramdisksdipath  \boot\boot.sdi

for /f "tokens=1-3" %%a in ('Bcdedit /store %BCD-File% /create /d "Windows 7 RUS Домашняя x86 - УДАЛЯЕТ ПАРТИЦИИ !!!" /application osloader') do set guid1=%%c
Bcdedit /store %BCD-File% /set %guid1% systemroot \Windows
Bcdedit /store %BCD-File% /set %guid1% detecthal Yes
Bcdedit /store %BCD-File% /set %guid1% winpe Yes
Bcdedit /store %BCD-File% /set %guid1% osdevice ramdisk=[boot]\Boot\winpe.wim,{ramdiskoptions}
Bcdedit /store %BCD-File% /set %guid1% device ramdisk=[boot]\Boot\winpe.wim,{ramdiskoptions}

for /f "tokens=1-3" %%a in ('Bcdedit /store %BCD-File% /create /d "Windows 7 RUS x86 Все в одном" /application osloader') do set guid2=%%c
Bcdedit /store %BCD-File% /set %guid2% systemroot \Windows
Bcdedit /store %BCD-File% /set %guid2% detecthal Yes
Bcdedit /store %BCD-File% /set %guid2% winpe Yes
Bcdedit /store %BCD-File% /set %guid2% osdevice ramdisk=[boot]\Boot\winpe2.wim,{ramdiskoptions}
Bcdedit /store %BCD-File% /set %guid2% device ramdisk=[boot]\Boot\winpe2.wim,{ramdiskoptions}

for /f "tokens=1-3" %%a in ('Bcdedit /store %BCD-File% /create /d "Windows 7 EN RUS ROM IT x86 x64 Все в одном - Задаёт все вопросы" /application osloader') do set guid3=%%c
Bcdedit /store %BCD-File% /set %guid3% systemroot \Windows
Bcdedit /store %BCD-File% /set %guid3% detecthal Yes
Bcdedit /store %BCD-File% /set %guid3% winpe Yes
Bcdedit /store %BCD-File% /set %guid3% osdevice ramdisk=[boot]\Boot\winpe-aio.wim,{ramdiskoptions}
Bcdedit /store %BCD-File% /set %guid3% device ramdisk=[boot]\Boot\winpe-aio.wim,{ramdiskoptions}

for /f "tokens=1-3" %%a in ('Bcdedit /store %BCD-File% /create /d "Windows Vista SP2 EN RUS x86 Все в одном" /application osloader') do set guid4=%%c
Bcdedit /store %BCD-File% /set %guid4% systemroot \Windows
Bcdedit /store %BCD-File% /set %guid4% detecthal Yes
Bcdedit /store %BCD-File% /set %guid4% winpe Yes
Bcdedit /store %BCD-File% /set %guid4% osdevice ramdisk=[boot]\Boot\vista86.wim,{ramdiskoptions}
Bcdedit /store %BCD-File% /set %guid4% device ramdisk=[boot]\Boot\vista86.wim,{ramdiskoptions}



Bcdedit /store %BCD-File% /create {bootmgr} /d "Windows Seven BLOOD MANAGER"
Bcdedit /store %BCD-File% /set {bootmgr} timeout 30
Bcdedit /store %BCD-File% /set {bootmgr} displayorder %guid1% %guid2% %guid3% %guid4%

Bcdedit /store %BCD-File% /enum all
BoRoDa
 
Сообщения: 4
Зарегистрирован: 07 фев 2009, 09:18

Re: BCD - для Windows 7

Сообщение Devils » 17 мар 2011, 18:27

Сделал нечто похожее, как у BoRoDa, но есть несколько вопросов.
1. Русификация меню. (хотелось бы)
2.
Код: Выделить всё
Windows Boot Manager
--------------------
identifier              {bootmgr}
description             Windows Boot Manager
displayorder            {f05800fb-50a9-11e0-b933-485b39262c77}
                        {f477d1e1-50a9-11e0-b933-485b39262c77}
timeout                 30

Windows Boot Loader
-------------------
identifier              {f05800fb-50a9-11e0-b933-485b39262c77}
device                  ramdisk=[boot]\boot\winpe.wim,{ramdiskoptions}
description             Windows 7 x86
locale                     ru-RU
osdevice                ramdisk=[boot]\boot\winpe.wim,{ramdiskoptions}
systemroot              \Windows
detecthal               Yes
winpe                   Yes

Windows Boot Loader
-------------------
identifier              {f477d1e1-50a9-11e0-b933-485b39262c77}
device                  ramdisk=[boot]\boot\winpe_x64.wim,{ramdiskoptions}
description             Windows 7 x64
locale                     ru-RU
osdevice                ramdisk=[boot]\boot\winpe_x64.wim,{ramdiskoptions}
systemroot              \Windows
detecthal               Yes
winpe                   Yes

Вместо названий Windows 7 x86 и Windows 7 x64, выдает Ramdisk options и Ramdisk options
Как побороть это?
Devils
 
Сообщения: 231
Зарегистрирован: 25 июн 2009, 16:40
Откуда: Подмосковье

Re: BCD - для Windows 7

Сообщение Devils » 12 июн 2011, 13:31

Кто нибудь решил эту проблему?
Devils
 
Сообщения: 231
Зарегистрирован: 25 июн 2009, 16:40
Откуда: Подмосковье

Re: BCD - для Windows 7

Сообщение SkaN2412 » 04 окт 2011, 19:14

Вот у меня тот же бред. Мне нужно не удаляя разделов установить, все руками делать. Со сценарием из второго поста мне это дадут сделать?
SkaN2412
 
Сообщения: 6
Зарегистрирован: 24 авг 2011, 21:12

Re: BCD - для Windows 7

Сообщение Devils » 04 окт 2011, 22:30

Содержимое CreateBCD.cmd
Код: Выделить всё
@Echo off
Title Редактирование BCD-файла
SetLocal enabledelayedexpansion
for /f  "tokens=2 delims==" %%a in ('FindStr /IB "path2BCD" "settings.ini"') do set path2BCD=%%a
for /f  "tokens=2 delims==" %%b in ('FindStr /IB "ramdisksdipath" "settings.ini"') do set ramdisksdipath=%%b
for /f  "tokens=2 delims==" %%d in ('FindStr /IB "path2winpe" "settings.ini"') do set path2winpe=%%d
for /f  "tokens=2 delims==" %%e in ('FindStr /IB "path2_x64" "settings.ini"') do set path2_x64=%%e
REM if not exist %path2BCD% echo path2BCD не существует. Укажите правильный путь в settings.ini && pause && exit

:create_BCD
REM Создание Хранилища BCD
bcdedit -createstore %path2BCD% >nul
bcdedit -store %path2BCD% -create {ramdiskoptions}
bcdedit -store %path2BCD% -set {ramdiskoptions} ramdisksdidevice boot >nul
bcdedit -store %path2BCD% -set {ramdiskoptions} ramdisksdipath %ramdisksdipath% >nul

for /F "tokens=2 delims={}" %%i in ('bcdedit -store %path2BCD% -create /d "Windows 7 x86" /application osloader') do set guidx86={%%i}
bcdedit -store %path2BCD% -set %guidx86% systemroot \Windows >nul
bcdedit -store %path2BCD% -set %guidx86% detecthal Yes >nul
bcdedit -store %path2BCD% -set %guidx86% winpe Yes >nul
bcdedit -store %path2BCD% -set %guidx86% osdevice ramdisk=[boot]%path2winpe%,{ramdiskoptions} >nul
bcdedit -store %path2BCD% -set %guidx86% device ramdisk=[boot]%path2winpe%,{ramdiskoptions} >nul

:choice
set /P x64=Добавление x64-разряндного загрузчика: Да - 1, Нет -2:
if %x64%==1 goto x64
if %x64%==2 (goto disload) Else (
Echo Неверно указан вариант. Нажмите 1 или 2
Echo.
goto choice)

:x64
for /F "tokens=2 delims={}" %%j in ('bcdedit -store %path2BCD% -create /d "Windows 7 x64" /application osloader') do set guidx64={%%j}
bcdedit -store %path2BCD% -set %guidx64% systemroot \Windows >nul
bcdedit -store %path2BCD% -set %guidx64% detecthal Yes >nul
bcdedit -store %path2BCD% -set %guidx64% winpe Yes >nul
bcdedit -store %path2BCD% -set %guidx64% osdevice ramdisk=[boot]%path2_x64%,{ramdiskoptions} >nul
bcdedit -store %path2BCD% -set %guidx64% device ramdisk=[boot]%path2_x64%,{ramdiskoptions} >nul

:disload
REM Создание записей в диспетчере загрузки
bcdedit -store %path2BCD% -create {bootmgr} /d "Windows Seven BootManager" >nul
bcdedit -store %path2BCD% -set {bootmgr} timeout 10 >nul
REM bcdedit -store %path2BCD% -set {bootmgr} locale ru-RU
bcdedit -store %path2BCD% -set {bootmgr} displayorder %guidx86% %guidx64% >nul
pause

Содержимое settings.ini
Код: Выделить всё
[Paths]
path2BCD=.\BCD
ramdisksdipath=\boot\boot.sdi
path2winpe=\W7\Sources\boot.wim
path2_x64=\W7\Sources\boot_x64.wim
Devils
 
Сообщения: 231
Зарегистрирован: 25 июн 2009, 16:40
Откуда: Подмосковье

Re: BCD - для Windows 7

Сообщение SkaN2412 » 05 окт 2011, 12:06

FINDSTR: Не удается открыть settings.ini
FINDSTR: Не удается открыть settings.ini
FINDSTR: Не удается открыть settings.ini
FINDSTR: Не удается открыть settings.ini

где его положить надо?
SkaN2412
 
Сообщения: 6
Зарегистрирован: 24 авг 2011, 21:12

Re: BCD - для Windows 7

Сообщение Devils » 05 окт 2011, 19:36

На одном уровне с createbcd.cmd
Devils
 
Сообщения: 231
Зарегистрирован: 25 июн 2009, 16:40
Откуда: Подмосковье

Re: BCD - для Windows 7

Сообщение SkaN2412 » 06 окт 2011, 06:14

странно, я его там и клал, но все равно не находит...
SkaN2412
 
Сообщения: 6
Зарегистрирован: 24 авг 2011, 21:12

Re: BCD - для Windows 7

Сообщение SkaN2412 » 07 окт 2011, 21:17

заметил, что стопорится после того, как пытается отправить пару файлов (последний - файл шрифтов). и во вкладке TFTP пишется, что два раза ERROR при отправке файла BCD...
причем это я попробовал с еще одного компа. на который как раз винда встала исправно таким методом, без геморроя
SkaN2412
 
Сообщения: 6
Зарегистрирован: 24 авг 2011, 21:12

След.

Вернуться в Установка Windows Vista и Windows 7 по сети

Кто сейчас на конференции

Сейчас этот форум просматривают: Yahoo [Bot] и гости: 1

cron
@Mail.ru